PRO dustemwrap_plot, p_dim,                           $
                     st=st,                           $
                     dustem_sed = dustem_sed,         $
                     SED_spec = SED_spec,             $
                     dustem_qsed = dustem_qsed,       $
                     Q_spec = Q_spec,                 $
                     dustem_used = dustem_used,       $
                     U_spec = U_spec,                 $
                     dustem_polsed = dustem_polsed,   $
                     P_spec = P_spec,                 $
                     dustem_polfrac = dustem_polfrac, $
                     SP_spec = SP_spec,               $
                     dustem_psi_em = dustem_psi_em,   $
                     PSI_spec = PSI_spec,             $
                     dustem_ext = dustem_ext,         $
                     EXT_spec = EXT_spec,             $
                     dustem_qext = dustem_qext,       $
                     QEXT_spec = QEXT_spec,           $
                     dustem_uext = dustem_uext,       $
                     UEXT_spec = UEXT_spec,           $
                     dustem_polext = dustem_polext,   $
                     POLEXT_spec = POLEXT_spec,       $
                     dustem_fpolext = dustem_fpolext, $
                     SPEXT_spec = SPEXT_spec,         $
                     dustem_psi_ext = dustem_psi_ext, $
                     PSIEXT_spec = PSIEXT_spec,       $
                     _extra=_extra,                   $
                     help=help

;+
; NAME:
;    dustemwrap_plot
;
; PURPOSE:
;    plots dustemwrap observed sed, predicted sed, predicted spectra for total intensity, polarization in emission and extinction
;
; CATEGORY:
;    DustEMWrap, Distributed, Plotting, Mid-Level
;  
; CALLING SEQUENCE:
;    dustemwrap_plot,p_dim,st=st,dustem_sed=dustem_sed,SED_spec=SED_spec,dustem_qsed=dustem_qsed,Q_spec=Q_spec,dustem_used=dustem_used,U_spec=U_spec $
;                  ,dustem_polsed,P_spec,dustem_polfrac,SP_spec,dustem_psi_em,PSI_spec $
;                  ,dustem_ext,EXT_spec,dustem_qext,QEXT_spec,dustem_uext,UEXT_spec $
;                  ,dustem_polext,POLEXT_spec,dustem_fpolext,SPEXT_spec,dustem_psi_ext,PSIEXT_spec $
;                  ,_extra=_extra 
;
; INPUTS:
;    p_dim
;
; OPTIONAL INPUT PARAMETERS:
;    st             = dustem output structure 
;    dustem_sed     = dustem predicted SED
;    dustem_qsed    = dustem predicted StokesQ SED
;    dustem_used    = dustem predicted StokesU SED
;    dustem_polsed  = dustem predicted LargeP SED
;    dustem_polfrac = dustem predicted smallP SED  
;    dustem_psi_em  = dustem predicted PSI SED  
;    dustem_ext     = dustem predicted EXT
;    dustem_qext    = dustem predicted StokesQ EXT
;    dustem_uext    = dustem predicted StokesU EXT 
;    dustem_polext  = dustem predicted LargeP EXT
;    dustem_fpolext = dustem predicted smallP EXT
;    dustem_psi_ext = dustem prediced PSI EXT 
;    SED_spec       = dustem predicted total emission spectrum (total = all-grain)
;    Q_spec         = dustem precicted total StokesQ emission spectrum
;    U_spec         = dustem predicted total Stokes U emission spectrum
;    P_spec         = dustem predicted total LargeP emission spectrum
;    SP_spec        = dustem predicted total smallP emission spectrum 
;    PSI_spec       = dustem predicted total PSI emission spectrum
;    EXT_spec       = dustem predicted total extinction spectrum
;    QEXT_spec      = dustem predicted total StokesQ extinction spectrum
;    UEXT_spec      = dustem predicted total StokesU extinction spectrum
;    POLEXT_spec    = dustem predicted total LargeP extinction spectrum
;    SPEXT_spec     = dustem predicted total smallP extinction spectrum  
;    PSIEXT_spec    = dustem predicted total PSI extinction spectrum
;
; OUTPUTS:
;    dustem_sed     = dustem predicted SED
;    dustem_qsed    = dustem predicted StokesQ SED
;    dustem_used    = dustem predicted StokesU SED
;    dustem_polsed  = dustem predicted LargeP SED
;    dustem_polfrac = dustem predicted smallP SED  
;    dustem_psi_em  = dustem predicted PSI SED  
;    dustem_ext     = dustem predicted EXT
;    dustem_qext    = dustem predicted StokesQ EXT
;    dustem_uext    = dustem predicted StokesU EXT 
;    dustem_polext  = dustem predicted LargeP EXT
;    dustem_fpolext = dustem predicted smallP EXT
;    dustem_psi_ext = dustem prediced PSI EXT 
;    SED_spec       = dustem predicted total emission spectrum
;    Q_spec         = dustem precicted total StokesQ emission spectrum
;    U_spec         = dustem predicted total Stokes U emission spectrum
;    P_spec         = dustem predicted total LargeP emission spectrum
;    SP_spec        = dustem predicted total smallP emission spectrum 
;    PSI_spec       = dustem predicted total PSI emission spectrum
;    EXT_spec       = dustem predicted total extinction spectrum
;    QEXT_spec      = dustem predicted total StokesQ extinction spectrum
;    UEXT_spec      = dustem predicted total StokesU extinction spectrum
;    POLEXT_spec    = dustem predicted total LargeP extinction spectrum
;    SPEXT_spec     = dustem predicted total smallP extinction spectrum  
;    PSIEXT_spec    = dustem predicted total PSI extinction spectrum;
;
; OPTIONAL OUTPUT PARAMETERS:
;    
; ACCEPTED KEY-WORDS:
;    help
;
; COMMON BLOCKS:
;    None
;
; SIDE EFFECTS:
;    Generates plots!
;
; RESTRICTIONS:
;    The DustEM fortran code must be installed
;    The DustEMWrap IDL code must be installed
;
; PROCEDURES AND SUBROUTINES USED:
;
; EXAMPLES:
;    
; MODIFICATION HISTORY:
;    Written by Ilyes Choubani 2022
;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  
;-

IF keyword_set(help) THEN BEGIN
  doc_library,'dustemwrap_plot'
  goto,the_end
END

;===========Making sure Plugins are activated
;==== JPB: why is this needed here ??
IF not keyword_set(st) THEN BEGIN
  dustem_activate_plugins,p_dim/(*(*!dustem_fit).param_init_values),st=st  ; 0/0 division case?
ENDIF
;print,p_dim/(*(*!dustem_fit).param_init_values)
;stop

;===========Making sure the predicted dustem SEDs are set
if not keyword_set(dustem_sed) and isa((*!dustem_data).sed) then begin ;better test?
      dustem_sed = dustem_compute_sed(p_dim,st=st,SED_spec=SED_spec)
      if !run_pol and tag_exist(*!dustem_show,'qsed') && !run_lin then begin
          dustem_polsed = dustem_compute_polsed(p_dim,st=st,P_spec=P_spec,SP_spec=SP_spec,dustem_polfrac=dustem_polfrac)
          toto = dustem_compute_stokes(p_dim,st=st,Q_spec=Q_spec,U_spec=U_spec,PSI_spec=PSI_spec,dustem_psi_em=dustem_psi_em) 
          dustem_qsed = toto[0]
          dustem_used = toto[1]
      endif         
endif
  
;===========Making sure the predicted dustem EXTs are set
if not keyword_set(dustem_ext) and isa((*!dustem_data).ext) then begin
      dustem_ext = dustem_compute_ext(p_dim,st=st,EXT_spec=EXT_spec)
      
      if !run_pol and tag_exist(*!dustem_show,'qext') && !run_lin then begin ;any polarization tag (qsed,used,qext,usext,polfrac) can be used for this test
                              
          dustem_polext = dustem_compute_polext(p_dim,st=st,POLEXT_spec=POLEXT_spec,SPEXT_spec=SPEXT_spec,dustem_fpolext=dustem_fpolext)
          toto = dustem_compute_stokext(p_dim,st=st,QEXT_spec=QEXT_spec,UEXT_spec=UEXT_spec,PSIEXT_spec=PSIEXT_spec,dustem_psi_ext=dustem_psi_ext) 
          dustem_qext = toto[0]
          dustem_uext = toto[1]
      endif
endif

;stop

;===========We should call this something more adequate
mouchard=*!iteration_mouchard
new_mouchard=mouchard[0]
new_mouchard.iteration=!dustem_iter.act
new_mouchard.chi2=(*!dustem_fit).chi2
new_mouchard.rchi2=(*!dustem_fit).rchi2
mouchard=[mouchard,new_mouchard]
!iteration_mouchard=ptr_new(mouchard)


;===========Initializing tests
test_sed = isa((*!dustem_data).sed) 
test_ext = isa((*!dustem_data).ext)

;===========Bunch of tests that are not important now but that
;might be in future releases. To adjust the layout of the dashboard for instance
if !run_pol then begin
    if tag_exist(*!dustem_show,'qsed') then begin ;testing to account for the fact that the user can activate the !run_pol keyword without knowing
    ;ie: using a dust model with polarization w/o polarization data present...
        test_polsed = isa((*!dustem_show).polsed)
        test_polfrac = isa((*!dustem_show).polfrac)
        test_qsed = isa((*!dustem_show).qsed)
        test_used = isa((*!dustem_show).used)
        test_psi_em = isa((*!dustem_show).psi_em)
    endif
    
    if tag_exist(*!dustem_show,'qext') then begin
        test_polext = isa((*!dustem_show).polext)
        test_psi_ext = isa((*!dustem_show).psi_ext)
        test_fpolext = isa((*!dustem_show).fpolext)
        test_qext = isa((*!dustem_show).qext)
        test_uext = isa((*!dustem_show).uext)
    endif
    
    if tag_exist(*!dustem_show,'qsed') then test_m = test_sed or test_polsed $
                                                  or test_polfrac or test_qsed $
                                                  or test_used or test_psi_em
    if tag_exist(*!dustem_show,'qext') then test_x = test_ext or test_polext $
                                                  or test_fpolext or test_qext $
                                                  or test_uext or test_psi_ext
                                                  
    if ~tag_exist(*!dustem_show,'qsed') then test_m = test_sed
    if ~tag_exist(*!dustem_show,'qext') then test_x = test_ext 
                                        
endif else begin
    test_m = test_sed 
    test_x = test_ext 
endelse
;stop

;n_plgns = n_tags(*!dustem_plugin)
n_plgns = n_elements(*!dustem_plugin)

frmt0='(A36)'
frmt1='(1E10.2)'
frmt2='(10F10.2)'

;===========Loops over the _extra structure and retrieves 
;the keywords pertaining to each data set.
;It places them in a system variable that is 
;always refreshed (@ each call). 
dustem_set_plot_range,test_sed, test_ext,_extra= _extra

;===========Keeping track of the command indices to adress the different datasets
;Doing this manually because I don't see another way.
cmdind_m = 0 ;for emission
cmdind_x = 0 ;for extinction
cmdind_prms = 0 ;for parameters
cmdind_plgns = 0 ;for plugins

;===========Keeping track of the windows' indices
;-emission and extinction-
iswinsed = !dustemcgwin_id.sed EQ la_undef()
iswinext = !dustemcgwin_id.ext EQ la_undef()

;===========Keeping track of the windows' indices
;-parameters and plugins-
iswinprms = !dustemcgwin_id.prms EQ la_undef()
iswinplgns = !dustemcgwin_id.plgns EQ la_undef()

;===========Retrieving some data relevant to the plotting
if isa((*!dustem_fit).current_param_errors) then begin
    errors = (*(*!dustem_fit).current_param_errors) ;* (*(*!dustem_fit).param_init_values) ;multiplied internally in dustem_mpfit. Should maybe be changed.
endif else begin
    errors = (*(*!dustem_fit).param_init_values)*0.;+la_undef();Initialized to 0 instead of la_undef() 
ENDELSE 

if isa((*!dustem_fit).chi2) then begin
    chi2 = (*!dustem_fit).chi2    
endif else begin
    chi2 = la_undef();maybe not the best initialization 
endelse 

if isa((*!dustem_fit).rchi2) then begin
    rchi2 = (*!dustem_fit).rchi2    
endif else begin
    rchi2 = la_undef();maybe not the best initialization 
endelse 

;changing tag_exist() by isa() because the user can mistakenly activate the !run_pol keyword

;===== commented out by Annie and JP on 17 march 2023
;If !run_pol THEN BEGIN
;    If tag_exist(*!dustem_show,'QSED') THEN BEGIN
;        IF ~isa((*!dustem_data).qsed) THEN !run_pol=0 
;    ENDIF ELSE !run_pol = 0
;ENDIF

;===========Window positionning parameters
if !run_pol and tag_exist(*!dustem_show,'qsed') then BEGIN ;qsed tag is sufficient for the test
    wdelta_x=60
    main_wxsize=910
    main_wysize=658

    param_wxpos=main_wxsize+wdelta_x
    param_wypos=15
    param_wxsize=350
    param_wysize=200

    plugin_wxpos=main_wxsize+wdelta_x
    plugin_wypos=300
    plugin_wxsize=350
    plugin_wysize=200
ENDIF ELSE BEGIN
    wdelta_x=60
    main_wxsize=640  ;default of cgwindow
    main_wysize=512  ;default of cgwindow

    param_wxpos=main_wxsize+wdelta_x;700
    param_wypos=15
    param_wxsize=350
    param_wysize=200

    plugin_wxpos=main_wxsize+wdelta_x;700
    plugin_wypos=300
    plugin_wxsize=350
    plugin_wysize=200
ENDELSE

;===========EMISSION WINDOW
if test_m then begin
    
    ;===========If window not set, create it and plot data anew
    if iswinsed then begin    
        
        cgwindow,wxsize=main_wxsize,wysize=main_wysize,wtitle='DUSTEMWRAP '+!dustem_version.version+' (EMISSION)' 
                                                        
        winid_m = cgquery(dimensions=dim_m,/current) ;dimension is not used...
        !dustemcgwin_id.sed = winid_m
        
        cgcontrol, winid_m, execute=0
       
        ;===========Display Model string
        xxpos = 0.015
        yypos = 0.97
        cgtext, xxpos, yypos,'Model : '+!dustem_model,color=0,/normal,charsize = 1.2,/addcmd ;& cmdind_m+=1 This is the first command in the window
        ;===========Display Hydrogen Column Density
        yypos = 0.95
        cgtext, xxpos, yypos,textoidl('N_{H}')+textoidl(' (H/cm^2) : ')+strmid(string(*!dustem_HCD,format='(1E10.2)'),2),color=0,/normal,charsize = 1.2,/addcmd & cmdind_m+=1
        
        ;===========Displaying current iteration
        xxpos = 0.015 
        yypos = 0.015
        
        ;FROZEN part that does not change in-between displays.
        cgtext, xxpos, yypos,'Iteration : ',color=0,/normal,charsize = 1.25,/addcmd & cmdind_m+=1
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen('Iteration : ')))
         
        ;Refreshed part that changes in-between iterations/displays.
        cgtext, xxpos, yypos,esc_txt+strtrim(!dustem_iter.act,2),color=0,/normal,charsize = 1.25,/addcmd & cmdind_m+=1
        
        ;
        !dustemcgwin_ncmds.runs.pl = cmdind_m

        ;#plotting of (mostly) fixed data for rchi2
          
        yypos = 0.97
          
        ;#Displaying fixed part
        ;replacing the chi2 value (refreshed part of the string) by spaces
        esc_txt = strjoin(replicate(' ', strlen(strtrim(string(chi2,format=frmt2),2))))
        cgtext, 0.985, yypos,textoidl('\chi^{2} :  ')+esc_txt,color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_m+=1
        
        
        ;#Displaying refreshed part (first run . This is the command that will be replaced)
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen(textoidl('\chi^{2} :  '))))
        cgtext, 0.985, yypos,esc_txt+strtrim(string(chi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_m+=1
       
        ;saving the command id to replace it
        !dustemcgwin_ncmds.chi2.pl = cmdind_m
        
        ;plotting of (mostly) fixed data for rchi2
        
        yypos = 0.95
        
        ;#Displaying fixed part
        ;replacing the rchi2 value (refreshed part of the string) by spaces
        esc_txt = strjoin(replicate(' ', strlen(strtrim(string(rchi2,format=frmt2),2))))
        txt = textoidl('r_{\chi^{2}} : ')
        
        cgtext, 0.985, yypos,txt+esc_txt,color=0,/normal,charsize = 1.35,alignment=1.0,/addcmd & cmdind_m+=1
        
        ;#Displaying refreshed part (first run . This is the command that will be replaced)
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen(textoidl('r_{\chi^{2}} : '))))
        txt = strtrim(string(rchi2,format=frmt2),2)
        cgtext, 0.985, yypos,esc_txt+txt,color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_m+=1
        ;saving the command id to replace it
        !dustemcgwin_ncmds.rchi2.pl = cmdind_m

        ;Saving the title for the emission plot
        tit=!dustem_plot_range.title_m
        
        ;See if JP and Annie don't like plotting this on the bottom of the window
        cgtext, 0.5, 0.96,tit,color=0,/normal,charsize = 1.6,alignment=0.5,/addcmd & cmdind_m+=1
        cgtext, 0.5, 0.015,'(RUNNING)',color=0,/normal,charsize = 1.6,/addcmd,alignment=0.5 & cmdind_m+=1
        
        !dustemcgwin_ncmds.pltit.pl = cmdind_m
        
    endif else begin     ;This is when the cgwindow exists already
        
        winid_m = !dustemcgwin_id.sed
        cgcontrol, winid_m, execute=0
        cgset, winid_m ;apparently specifying the window index in the above command isn't enough. This might be because of the use of cgcontrol
        
        ;Refreshing chi2 data: 
        cmdind_m = !dustemcgwin_ncmds.chi2.pl
        xxpos = 0.985;1 - !dustemcgwin_ncmds.chi2.txtwdth - 0.03  
        yypos = 0.97
        ;using cgwindow's weakness to fix the ps output.
        if !dustem_end ne 0 then esc_txt = textoidl('\chi^{2} :  ') else esc_txt = strjoin(replicate(' ', strlen(textoidl('\chi^{2} :  '))))
        cgwindow,'cgtext', xxpos , yypos,esc_txt+strtrim(string(chi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_m, winid=winid_m ;& cmdind_m+=1
        if !dustem_end ne 0 then  cgwindow,'cgtext', xxpos , yypos,'',color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_m-1, winid=winid_m ;& cmdind_m+=1
         ;Refreshing number of runs data: 
        ;Refreshing rchi2 data: 
        cmdind_m = !dustemcgwin_ncmds.rchi2.pl
        xxpos = 0.985;1 - !dustemcgwin_ncmds.rchi2.txtwdth - 0.03  
        yypos = 0.95
        ;using cgwindow's weakness to fix the ps output.        
        if !dustem_end ne 0 then esc_txt = textoidl('r_{\chi^{2}} : ') else esc_txt = strjoin(replicate(' ', strlen(textoidl('r_{\chi^{2}} : '))))
        cgwindow,'cgtext', xxpos , yypos,esc_txt+strtrim(string(rchi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_m, winid=winid_m ;& cmdind_m+=1
        if !dustem_end ne 0 then  cgwindow,'cgtext', xxpos , yypos,'',color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_m-1, winid=winid_m ;& cmdind_m+=1
        ;Refreshing number of runs data: 
        cmdind_m = !dustemcgwin_ncmds.runs.pl
        xxpos = 0.015;0.03 + !dustemcgwin_ncmds.runs.txtwdth*1.35  ;(because of charsize)
        yypos = 0.015
        esc_txt = strjoin(replicate(' ', strlen('Iteration : ')))
        if !dustem_iter.act eq 0 then txt = esc_txt+'Fit failed. '  else begin
            if !dustem_end ne 0 then esc_txt='Iteration : '
            txt = esc_txt+strtrim(!dustem_iter.act,2)
        endelse
        cgwindow,'cgtext', xxpos , yypos,txt,color=0,/normal,charsize = 1.25,/replacecmd,cmdindex=cmdind_m, winid=winid_m ;& cmdind_m+=1
        
        ;update of the title here ?
        
        if !dustem_end EQ 1 then begin  ;IF & ONLY IF we're at the last iteration (refreshing title)
            ;tit=!dustem_plot_range.title_m
            cmdind_m = !dustemcgwin_ncmds.pltit.pl
            
            xxpos = 0.5;!dustemcgwin_ncmds.pltit.txtwdth_m
            yypos = 0.015
        
            cgwindow,'cgtext', xxpos , yypos,'(Final Run)',alignment=0.5,color=0,/normal,charsize = 1.6,/replacecmd,cmdindex=cmdind_m, winid=winid_m  
        
        endif
        
        if !dustem_end EQ -1 then begin ;Adjusting title for subsequent displays to the end of the fit 
            
            tit=!dustem_plot_range.title_m
            cmdind_m = !dustemcgwin_ncmds.pltit.pl
            
            xxpos = 0.5
            yypos =0.96
                
            cgwindow,'cgtext', xxpos , yypos,tit,color=0,/normal,charsize = 1.6,/replacecmd,alignment=0.5,cmdindex=cmdind_m-1, winid=winid_m
            ;this following/below call is needed so that the string disappears (string is '(FINAL RUN)' or '(RUNNING)')
            ;just to be safe
            yypos = 0.015
            cgwindow,'cgtext', xxpos, yypos,'',color=0,/normal,charsize = 1.6,/replacecmd,alignment=0.5,cmdindex=cmdind_m, winid=winid_m
        ENDIF
       
    endelse
 
    ;This block needs to be replicated inside the dustem_plot_dataset routine
    
    if !run_pol and tag_exist(*!dustem_show,'qsed') then begin
        
        ;position arrays for plot and normalized graph
        
        ;THIS IS HARD-CODED IN A VERY SILLY WAY
        
        p_sed = [0.05,0.67,0.475,0.90]
        p_psed = [0.525,0.67,0.95,0.90]
        p_spsed = [0.05,0.375,0.475,0.575]
        p_psised = [0.525,0.375,0.95,0.575]
        p_qsed = [0.05,0.12,0.475,0.35]  
        p_used = [0.525,0.12,0.95,0.35]
        
        np_sed = [0.05,0.60,0.475,0.67]
        np_psed = [0.525,0.60,0.95,0.67]
        np_qsed = [0.05,0.05,0.475,0.12] 
        np_used = [0.525,0.05,0.95,0.12]
        
        p_sed[1]+= 0.0125 & p_sed[3]+= 0.0125 
        p_psed[1]+= 0.0125 & p_psed[3]+= 0.0125
        p_spsed[1]+= 0.0125 & p_spsed[3]+= 0.0125
        p_psised[1]+= 0.0125 & p_psised[3]+= 0.0125
        p_qsed[1]+= 0.0125 & p_qsed[3]+= 0.0125
        p_used[1]+= 0.0125 & p_used[3]+= 0.0125
        
        np_sed[1]+= 0.0125 & np_sed[3]+= 0.0125 
        np_psed[1]+= 0.0125 & np_psed[3]+= 0.0125
        np_qsed[1]+= 0.0125 & np_qsed[3]+= 0.0125
        np_used[1]+= 0.0125 & np_used[3]+= 0.0125
        
        
          
    endif else begin
        p_sed  = [0.07,0.30,0.97,0.88]
        np_sed = [0.07,0.12,0.97,0.30]
    
    endelse

    plotsym,0,/fill 
    
    
    if !run_pol and tag_exist(*!dustem_show,'qsed') then begin
        ;This part can be adjusted for future releases if the user wants to plot 
        ;specific datasets 
        
        ;lists because elements have different dimensions and/or we want entire arrays as elements
        dustem_interp = list(dustem_sed,dustem_polfrac,dustem_qsed,dustem_used,dustem_psi_em,dustem_polsed) ;DustEmWrap SED predictions
        dustem_spec = list(SED_spec,SP_spec,Q_spec,U_spec,PSI_spec,P_spec) ;DustEM spectra predictions
        extra_spec = list(0,SED_spec,0,0,0,0) ;extra spectra that the dataset needs in order to be plotted. 
        ;This (extra_spec use) actually should not be generalized since the only case we need an extra spectrum is when plotting the polarization fraction.
        position = list(list(p_sed,np_sed),list(p_spsed),list(p_qsed,np_qsed),list(p_used,np_used),list(p_psised),list(p_psed,np_psed))
        
        ;these don't have to be lists
        datasets = ['SED','POLFRAC','QSED','USED','PSI_EM','POLSED']
        ;but these can be combined using a list but we're leaving it as is for the moment...
        positiveonly = [0,0,1,1,0,0] ;used for q and u
        negativeonly = [0,0,1,1,0,0] ;used for q and u
    ENDIF ELSE BEGIN
    
        dustem_interp = list(dustem_sed) ;DustEmWrap SED predictions . 
        dustem_spec = list(SED_spec) ;DustEM spectra predictions
        position = list(p_sed,np_sed)  ;list(list(p_sed,np_sed)) ; I think I need this ...
        ;position_n =list(np_sed) 
        datasets = ['SED']
        ;replace by one keyword?
        positiveonly=[0] ;kept it for completeness. Also this loop reminds me that JP also wants the user to be able to display one dataset. 
        negativeonly=[0]
    ENDELSE
    
    if  ~iswinsed then begin ;PLOTTING OF REFRESHED DATA
         
         ;REFRESHING DATA  
         cmdind_m = !dustemcgwin_ncmds.sed.pl
         cgwindow,'dustem_plot_dataset', st, dustem_interp,dustem_spec,extra_spec=extra_spec,dataset=datasets, /refresh,position=position, positive_only=positiveonly,negative_only=negativeonly,winid=winid_m,cmdindex=cmdind_m,/replacecmd,_extra=_extra     
         
    endif else begin 
        
        ; PLOTTING OF DATA THAT IS UNCHANGED 
        cgwindow,'dustem_plot_dataset', st, dataset=datasets, position=position,positive_only=positiveonly,negative_only=negativeonly, /addcmd, winid=winid_m, _extra=_extra & cmdind_m+=1 
        ; REFRESHING DATA - to plot the refreshed data for the first time.
        cgwindow,'dustem_plot_dataset', st, dustem_interp,dustem_spec,extra_spec=extra_spec,dataset=datasets,positive_only=positiveonly,negative_only=negativeonly, /refresh ,position=position, /addcmd, winid=winid_m, _extra=_extra & cmdind_m+=1
        !dustemcgwin_ncmds.sed.pl = cmdind_m ;if this works I'll be able to get rid of one of the pointers
           
    endelse       
      
    cgcontrol, winid_m, execute=1
         
ENDIF 


;===========EXTINCION WINDOW
if test_x then begin
    
    ;===========If window not set, create it and plot data anew
    if iswinext then begin 
        ;stop
        cgwindow,wxsize=main_wxsize,wysize=main_wysize,wtitle='DUSTEMWRAP '+!dustem_version.version+' (EXTINCTION)';, wback='grey';,wobject=winobj_m
        winid_x = cgquery(dimensions=dim_x,/current) ;dimension is not used...
        !dustemcgwin_id.ext = winid_x
        
        cgcontrol, winid_x, execute=0
        
        ;===========Display Model string
        xxpos = 0.015
        yypos = 0.97
        ;===========Display Hydrogen Column Density
        cgtext, xxpos, yypos,'Model : '+!dustem_model,color=0,/normal,charsize = 1.2,/addcmd ;& cmdind_m+=1 This is the first command in the window
        yypos = 0.95
        cgtext, xxpos, yypos,textoidl('N_{H}')+textoidl(' (H/cm^2) : ')+strmid(string(*!dustem_HCD,format='(1E10.2)'),2),color=0,/normal,charsize = 1.2,/addcmd & cmdind_x+=1
        
        ;===========Displaying current iteration
        xxpos = 0.015 
        yypos = 0.015
        
       ;FROZEN part that does not change in-between displays.
        cgtext, xxpos, yypos,'Iteration : ',color=0,/normal,charsize = 1.25,/addcmd & cmdind_x+=1
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen('Iteration : ')))
         
        ;Refreshed part that changes in-between iterations/displays.
        cgtext, xxpos, yypos,esc_txt+strtrim(!dustem_iter.act,2),color=0,/normal,charsize = 1.25,/addcmd & cmdind_x+=1
        
        ;
        !dustemcgwin_ncmds.runs.pl = cmdind_x
        
        
        ;plotting of (mostly) fixed data for rchi2
        ;Since the format of the strings is specified, the length/width of the string in thex direction is fixed. 
        
        yypos = 0.97
        
        ;Displaying fixed part
        ;replacing the chi2 value (refreshed part of the string) by spaces
        esc_txt = strjoin(replicate(' ', strlen(strtrim(string(chi2,format=frmt2),2))))
        cgtext, 0.985, yypos,textoidl('\chi^{2} : ')+esc_txt,color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_x+=1
        
        ;Displaying refreshed part (first run . This is the command that will be replaced)
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen(textoidl('\chi^{2} :  '))))
        cgtext, 0.985, yypos,esc_txt+strtrim(string(chi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_x+=1
        
        ;saving the command id to replace it
        !dustemcgwin_ncmds.chi2.pl = cmdind_x
  
        ;plotting of (mostly) fixed data for rchi2
    
        yypos = 0.95
        
        ;Displaying fixed part
        ;relpacing the rchi2 value (refreshed part of the string) by spaces
        esc_txt = strjoin(replicate(' ', strlen(strtrim(string(rchi2,format=frmt2),2))))
        cgtext, 0.985, yypos,textoidl('r_{\chi^{2}} : ')+esc_txt,color=0,/normal,charsize = 1.35,alignment=1.0,/addcmd & cmdind_x+=1
        
        ;Displaying refreshed part (first run . This is the command that will be replaced)
        ;generating the equivalent escape string for the frozen part of the string
        esc_txt = strjoin(replicate(' ', strlen(textoidl('r_{\chi^{2}} : '))))
        cgtext, 0.985, yypos,strtrim(string(rchi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/addcmd & cmdind_x+=1
        ;saving the command id to replace it
        !dustemcgwin_ncmds.rchi2.pl = cmdind_x
        
        
        ;Plotting of the title of the dashboard (plot(s))
        
        ;Saving the title for the extinction plot
        tit=!dustem_plot_range.title_x;
        
        cgtext, 0.5, 0.96,tit,color=0,/normal,charsize = 1.6,alignment=0.5,/addcmd & cmdind_x+=1
        ;plotting the status on the bottom of the display window
        cgtext, 0.5, 0.015,'(RUNNING)',color=0,/normal,charsize = 1.6,alignment=0.5,/addcmd & cmdind_x+=1
            
        !dustemcgwin_ncmds.pltit.pl = cmdind_x
        
    endif else begin ;  refreshed runs 
    
        
        winid_x = !dustemcgwin_id.ext
        cgcontrol, winid_x, execute=0
        cgset, winid_x ;apparently specifying the window index above isn't enough. This might be because of the use of cgcontrol
        
        ;Refreshing chi2 data: 
        cmdind_x = !dustemcgwin_ncmds.chi2.pl
        xxpos = 0.985;1 - !dustemcgwin_ncmds.chi2.txtwdth - 0.03  
        yypos = 0.97
        ;using cgwindow's weakness to fix the ps output.
        if !dustem_end ne 0 then esc_txt = textoidl('\chi^{2} :  ') else esc_txt = strjoin(replicate(' ', strlen(textoidl('\chi^{2} :  '))))
        cgwindow,'cgtext', xxpos , yypos,esc_txt+strtrim(string(chi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_x, winid=winid_x ;& cmdind_m+=1
        if !dustem_end ne 0 then  cgwindow,'cgtext', xxpos , yypos,'',color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_x-1, winid=winid_x ;& cmdind_m+=1
         ;Refreshing number of runs data: 
        ;Refreshing rchi2 data: 
        cmdind_x = !dustemcgwin_ncmds.rchi2.pl
        xxpos = 0.985;1 - !dustemcgwin_ncmds.rchi2.txtwdth - 0.03  
        yypos = 0.95
        ;using cgwindow's weakness to fix the ps output.        
        if !dustem_end ne 0 then esc_txt = textoidl('r_{\chi^{2}} : ') else esc_txt = strjoin(replicate(' ', strlen(textoidl('r_{\chi^{2}} : '))))
        cgwindow,'cgtext', xxpos , yypos,esc_txt+strtrim(string(rchi2,format=frmt2),2),color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_x, winid=winid_x ;& cmdind_m+=1
        if !dustem_end ne 0 then  cgwindow,'cgtext', xxpos , yypos,'',color=0,/normal,charsize = 1.0,alignment=1.0,/replacecmd,cmdindex=cmdind_x-1, winid=winid_x ;& cmdind_m+=1
        ;Refreshing number of runs data: 
        cmdind_x = !dustemcgwin_ncmds.runs.pl
        xxpos = 0.015;0.03 + !dustemcgwin_ncmds.runs.txtwdth*1.35  ;(because of charsize)
        yypos = 0.015
        esc_txt = strjoin(replicate(' ', strlen('Iteration : ')))
        if !dustem_iter.act eq 0 then txt = esc_txt+'Fit failed. '  else begin
            if !dustem_end ne 0 then esc_txt='Iteration : '
            txt = esc_txt+strtrim(!dustem_iter.act,2)
        endelse
        cgwindow,'cgtext', xxpos , yypos,txt,color=0,/normal,charsize = 1.25,/replacecmd,cmdindex=cmdind_x, winid=winid_x ;& cmdind_m+=1
        
        ;update of the title here ?
        
        if !dustem_end EQ 1 then begin  ;IF & ONLY IF we're at the last iteration (refreshing title)
            ;tit=!dustem_plot_range.title_m
            cmdind_x = !dustemcgwin_ncmds.pltit.pl
            
            xxpos = 0.5;!dustemcgwin_ncmds.pltit.txtwdth_m
            yypos = 0.015
        
            cgwindow,'cgtext', xxpos , yypos,'(Final Run)',alignment=0.5,color=0,/normal,charsize = 1.6,/replacecmd,cmdindex=cmdind_x, winid=winid_x  
        
        endif
        
        if !dustem_end EQ -1 then begin ;Adjusting title for subsequent displays to the end of the fit 
            
            tit=!dustem_plot_range.title_x
            cmdind_x = !dustemcgwin_ncmds.pltit.pl
            
            xxpos = 0.5
            yypos =0.96
                
            cgwindow,'cgtext', xxpos , yypos,tit,color=0,/normal,charsize = 1.6,/replacecmd,alignment=0.5,cmdindex=cmdind_x-1, winid=winid_x
            ;this following/below call is needed so that the string disappears (string is '(FINAL RUN)' or '(RUNNING)')
            ;just to be safe
            yypos = 0.015
            cgwindow,'cgtext', xxpos, yypos,'',color=0,/normal,charsize = 1.6,/replacecmd,alignment=0.5,cmdindex=cmdind_x, winid=winid_x
        ENDIF 
        
    endelse
    
    if !run_pol and tag_exist(*!dustem_show,'qext') then begin
      
        ;position arrays for plot and normalized graph
        
        ;THIS IS HARD-CODED IN A VERY SILLY WAY
        
        p_ext = [0.05,0.67,0.475,0.90]
        p_pext = [0.525,0.67,0.95,0.90]
        p_spext = [0.05,0.375,0.475,0.575] ; Should we plot this? tau_polext/tau_ext_tot. YES FOR NOW...
        p_psiext = [0.525,0.375,0.95,0.575]
        p_qext = [0.05,0.12,0.475,0.35]  
        p_uext = [0.525,0.12,0.95,0.35]
        
        np_ext = [0.05,0.60,0.475,0.67]
        np_pext = [0.525,0.60,0.95,0.67]
        np_qext = [0.05,0.05,0.475,0.12] 
        np_uext = [0.525,0.05,0.95,0.12]
        
        p_ext[1]+= 0.0125 & p_ext[3]+= 0.0125 
        p_pext[1]+= 0.0125 & p_pext[3]+= 0.0125
        p_spext[1]+= 0.0125 & p_spext[3]+= 0.0125
        p_psiext[1]+= 0.0125 & p_psiext[3]+= 0.0125
        p_qext[1]+= 0.0125 & p_qext[3]+= 0.0125
        p_uext[1]+= 0.0125 & p_uext[3]+= 0.0125
        
        np_ext[1]+= 0.0125 & np_ext[3]+= 0.0125 
        np_pext[1]+= 0.0125 & np_pext[3]+= 0.0125
        np_qext[1]+= 0.0125 & np_qext[3]+= 0.0125
        np_uext[1]+= 0.0125 & np_uext[3]+= 0.0125
        
        
          
    endif else begin
        p_ext  = [0.07,0.30,0.97,0.85]
        np_ext = [0.07,0.10,0.97,0.30]
    
    endelse

    ;Plotting of sed data axes (whether or not data is present)
    plotsym,0,/fill ;you might need to execute this again. hmm...

    if !run_pol and tag_exist(*!dustem_show,'qext') then begin
        ;This part can be adjusted for future releases if the user wants to plot specific datasets 
        
        ;lists because elements have different dimensions and/or we want entire arrays as elements
        dustem_interp = list(dustem_ext,dustem_fpolext,dustem_qext,dustem_uext,dustem_psi_ext,dustem_polext) ;DustEmWrap SED predictions
        dustem_spec = list(EXT_spec,SPEXT_spec,QEXT_spec,UEXT_spec,PSIEXT_spec,POLEXT_spec) ;DustEM spectra predictions
        extra_spec = list(0,EXT_spec,0,0,0,0) ;extra spectra that the dataset needs in order to be plotted. 
        ;This (extra_spec use) actually should not be generalized since the only case we need an extra spectrum is when plotting the polarization fraction.
        position = list(list(p_ext,np_ext),list(p_spext),list(p_qext,np_qext),list(p_uext,np_uext),list(p_psiext),list(p_pext,np_pext))
        
        ;these don't have to be lists
        datasets = ['EXT','FPOLEXT','QEXT','UEXT','PSI_EXT','POLEXT']
        ;but these can be combined using a list but we're leaving it as is for the moment...
        positiveonly = [0,0,1,1,0,0] ;used for q and u
        negativeonly = [0,0,1,1,0,0] ;used for q and u
    ENDIF ELSE BEGIN
    
        dustem_interp = list(dustem_ext) ;DustEmWrap EXT predictions . 
        dustem_spec = list(EXT_spec) ;DustEM spectra predictions
        position = list(p_ext,np_ext);list(list(p_sed,np_sed)) ; I think I need this ...
        ;position_n =list(np_sed) 
        datasets = ['EXT']
        ;replace by one keyword?
        positiveonly=[0] ;kept it for completeness. Also this loop reminds me that JP also wants the user to be able to display one dataset. 
        negativeonly=[0]
    ENDELSE
    
    if  ~iswinext then begin ;PLOTTING OF REFRESHED DATA
         
         ;REFRESHING DATA  
         cmdind_x = !dustemcgwin_ncmds.ext.pl
         cgwindow,'dustem_plot_dataset', st, dustem_interp,dustem_spec,extra_spec=extra_spec,dataset=datasets, /refresh,position=position, positive_only=positiveonly,negative_only=negativeonly,winid=winid_x,cmdindex=cmdind_x,/replacecmd,_extra=_extra     
         
    endif else begin 
        
        ; PLOTTING OF DATA THAT IS UNCHANGED 
        cgwindow,'dustem_plot_dataset', st, dataset=datasets, position=position,positive_only=positiveonly,negative_only=negativeonly, /addcmd, winid=winid_x, _extra=_extra & cmdind_x+=1 
        ; REFRESHING DATA - to plot the refreshed data for the first time.
        cgwindow,'dustem_plot_dataset', st, dustem_interp,dustem_spec,extra_spec=extra_spec,dataset=datasets,positive_only=positiveonly,negative_only=negativeonly, /refresh ,position=position, /addcmd, winid=winid_x, _extra=_extra & cmdind_x+=1
        !dustemcgwin_ncmds.ext.pl = cmdind_x ;if this works I'll be able to get rid of one of the pointers
           
    endelse       
        
    cgcontrol, winid_x, execute=1
     
          
ENDIF 


IF ~iswinprms THEN BEGIN;(NEXT RUNS)
    
    winid_prms = !dustemcgwin_id.prms
    cgcontrol, winid_prms, execute=0
    cgset, winid_prms
    cmdind_prms = !dustemcgwin_ncmds.prms.pl
    
    cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PARAMETERS'], /refresh,winid=winid_prms,cmdindex=cmdind_prms,/replacecmd, _extra=_extra
    
ENDIF ELSE BEGIN ;(FIRST RUN)
    cgwindow,wxpos=param_wxpos,wypos=param_wypos,wxsize=param_wxsize,wysize=param_wysize,wtitle='DUSTEMWRAP '+!dustem_version.version+' (PARAMETERS)' ; keeping the same y dimension of the emission/extinction plot? 

    winid_prms = cgquery(dimensions=dim_prms,/current) ;we don't need the dimension of the window so far/ I don't know why I needed it before
    cgcontrol, winid_prms, execute=0
    !dustemcgwin_id.prms = winid_prms
    cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PARAMETERS'], /addcmd , winid=winid_prms,_extra=_extra ;& cmdind_prms+=1
    cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PARAMETERS'], /addcmd, /refresh , winid=winid_prms, _extra=_extra & cmdind_prms+=1
    !dustemcgwin_ncmds.prms.pl = cmdind_prms
     
ENDELSE
;==== This is actually where the plot is made
cgcontrol, winid_prms ,execute=1


;IF (tag_names(*!dustem_plugin))(0) NE 'NONE' THEN BEGIN  
IF (*!dustem_plugin)[0].name NE 'NONE' THEN BEGIN  
    IF ~iswinplgns THEN BEGIN;(NEXT RUNS)
        winid_plgns = !dustemcgwin_id.plgns
        cgcontrol, winid_plgns, execute=0
        cgset, winid_plgns
        cmdind_plgns = !dustemcgwin_ncmds.plgns.pl
        cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PLUGINS'], /refresh, winid=winid_plgns,/replacecmd,cmdindex=cmdind_plgns, _extra=_extra
    ENDIF ELSE BEGIN ;(FIRST RUN)
        cgwindow,wxpos=plugin_wxpos,wypos=plugin_wypos,wxsize=plugin_wxsize,wysize=plugin_wysize,wtitle='DUSTEMWRAP '+!dustem_version.version+' (PLUGINS)' ; keeping the same y dimension of the emission/extinction plot? 
        cgcontrol, winid_plgns, execute=0
        !dustemcgwin_id.plgns = winid_plgns
        cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PLUGINS'], /addcmd , winid=winid_plgns,_extra=_extra ;& cmdind_prms+=1
        cgwindow,'dustem_plot_dataset', st, p_dim, errors,dataset=['PLUGINS'], /addcmd, /refresh , winid=winid_plgns, _extra=_extra & cmdind_plgns+=1
        !dustemcgwin_ncmds.plgns.pl = cmdind_plgns
    ENDELSE
ENDIF
;stop
;message,'parameter values from p_dim:',/continue
;print,p_dim*(*(*!dustem_fit).PARAM_INIT_VALUES)
;message,'parameter values from !dustem_fit:',/continue
;print,*(*!dustem_fit).CURRENT_PARAM_VALUES*(*(*!dustem_fit).PARAM_INIT_VALUES)

cgcontrol, winid_plgns ,execute=1

if !dustem_end then !dustem_end = -1 ;so that the last iteration is only plotted once.



the_end:
;stop

END