subroutine ctrldat (icalnd,datjul,
     >                    iyear,imonth,iday,ihour,imin,isec,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.06.01 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - janvier 1991
c*AUT port. CISI
c*
c*ROL Theme : Modules de controle
c*ROL         Controle de validite de la date sous forme julienne
c*ROL         ou calendaire.
c*ROL           julienne   : date >= 14610.0
c*ROL           calendaire : prise en compte des annees bisextiles
c*ROL                               annee  >= 1990
c*ROL                        1 <=   mois   >= 12
c*ROL                        1 <=   jour   >= 28 29 30 31
c*ROL                        0 <=  heures  >= 24
c*ROL                        0 <= minutes  >= 59
c*ROL                        0 <= secondes >= 59
c*
c*PAR icalnd (I) : type de date (0 = julienne, 1 = calendaire)
c*
c*PAR datjul (I) : date julienne CNES fractionnaire (depuis le 01/01/1950)
c*
c*PAR iyear  (I) : annee
c*PAR imonth (I) : mois
c*PAR iday   (I) : jour
c*PAR ihour  (I) : heures
c*PAR imin   (I) : minutes
c*PAR isec   (I) : secondes
c*
c*PAR ier    (O) : indicateur de validite de la date
c*
c*NOT dates      : si date julienne choisie, mettre a 0 les parametres
c*NOT            : concernant la date calendaire et reciproquement.
c*
c*NOT ier        : 0 = OK     
c*NOT ier        : 1 = date incorrecte (ex : jour = 34)
c*NOT ier        : 2 = warning - date < 1990 (valide pour gsfc65)
c*
c*INF utilise    : sans objet
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.06.01 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      integer icalnd
      double precision datjul
      integer iyear, imonth, iday, ihour, imin, isec
      integer ier
c
c     ---------------------------------
c*FON Declaration des variables locales
c     ---------------------------------
c 
      integer ianmin,imomin,imomax,ijomin,ijomax(4),ihemin,ihemax
      integer imimin,imimax,isemin,isemax,iercal(6),i,iabis
      double precision dajmin
c*LOC Variables de travail intermediaires
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     --------------------------
c*FON Affectation des constantes
c     --------------------------
c
c*    Definition des data bornes
c
      data dajmin /14610.0d0/
      data ianmin /1990/
      data imomin /1/
      data imomax /12/
      data ijomin /1/
      data ijomax /31, 30, 29, 28/
      data ihemin /0/
      data ihemax /24/
      data imimin /0/
      data imimax /59/
      data isemin /0/
      data isemax /59/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier = 0
c
      do 10 i = 1, 6
         iercal(i) = 0
10    continue
c
c     ----------------------------
c*FON Controle de la date julienne
c     ----------------------------
c
      if (icalnd .eq. 0) then
c
         if (datjul .lt. dajmin .and. datjul .gt. 0.0d0) then
            ier = 2
         else if (datjul .le. 0.0d0) then
            ier = 1
         endif
c
c     ------------------------------
c*FON Controle de la date calendaire
c     ------------------------------
c
      elseif (icalnd .eq. 1) then
c
c        Controle de l'annee
c        -------------------
c
         if (iyear .lt. ianmin .and. iyear .gt. 0) then
            iercal(1) = 2
         else if (iyear .le. 0) then
            iercal(1)= 1
           endif
c
c        Controle du mois
c        ----------------
c 
         if (imonth .lt. imomin .or. imonth .gt. imomax) then
            iercal(2) = 1
         endif
c      
c        Controle du jour
c        ----------------
c
c        le jour est compris entre 1 et 31 pour les mois
c        1, 3, 5, 7, 8, 10, 12
c
         if (imonth .eq.  1 .or. imonth .eq. 3 .or. imonth .eq.  5 .or.
     >       imonth .eq.  7 .or. imonth .eq. 8 .or. imonth .eq. 10 .or.
     >       imonth .eq. 12) then
c
            if (iday .lt. ijomin .or. iday .gt. ijomax(1)) then
               iercal(3) = 1
             endif
c
c        le jour est compris entre 1 et 30 pour les mois 4,6,9,11
c
         elseif (imonth .eq. 4 .or. imonth .eq. 6 .or. imonth .eq. 9
     >           .or. imonth .eq. 11) then
c
            if (iday .lt. ijomin .or. iday .gt. ijomax(2)) then
               iercal(3) = 1
            endif
c
c        le jour est compris entre 1 et 28 ou 1 et 29 si annee
c        bisextile
c
         elseif (imonth .eq. 2) then
c
            iabis  = mod(iyear,4)
c
c           l'annee est bisextile
c
            if (iabis .eq. 0) then
               if (iday .lt. ijomin .or. iday .gt. ijomax(3)) then
                  iercal(3) = 1
               endif
            else
c
c           l'annee n'est pas bisextile
c
               if (iday .lt. ijomin .or. iday .gt. ijomax(4)) then
                  iercal(3) = 1
               endif
            endif
c
         endif
c
c        controle de l'heure
c        -------------------
c
         if (ihour .lt. ihemin .or. ihour .gt. ihemax) then
            iercal(4) = 1
         endif
c
c        controle des minutes
c        --------------------
c
         if (imin .lt. imimin .or. imin .gt. imimax) then
            iercal(5) = 1
         endif
c
c        controle des secondes
c        ---------------------
c
         if (isec .lt. isemin .or. isec .gt. isemax) then
            iercal(6) = 1
         endif
c
c        traitement des erreurs concernant la date calendaire
c        ----------------------------------------------------
c
         if (iercal(1) .eq. 1 .or. iercal(2) .eq. 1 .or.
     >       iercal(3) .eq. 1 .or. iercal(4) .eq. 1 .or.  
     >       iercal(5) .eq. 1 .or. iercal(6) .eq. 1) then
            ier = 1
         elseif (iercal(1) .eq. 2) then
            ier = 2
         endif
c
      endif
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end