subroutine calpos (ihour,imin,isec,xikm,yikm,zikm,rig,rgdip,
     >                   rgsm,rggsm,rgse,xi,yi,zi,xg,yg,zg,rre,
     >                   thetr,phir,xlatgm,xlongm,xse,yse,zse,
     >                   xsm,ysm,zsm,xgsm,ygsm,zgsm,
     >                   tglsat,tlsat,xlatse,xlonse,tlose,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.05.30 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - juin 1995
c*AUT port. CISI 
c*
c*ROL Theme : Calculs de geophysique
c*ROL         Calcul des coordonnees du satellite dans le repere
c*ROL         inertiel, geographique, solaire ecliptique, solaire
c*ROL         magnetique, solaire magnetospherique, les latitudes
c*ROL         et longitudes ainsi que le temps geomagnetique local
c*ROL         et le temps local a partir de la date du calcul et
c*ROL         des coordonnees inertielles du satellite.
c*ROL         Les matrices de changement de repere sont passees en
c*ROL         parametre.
c*
c*PAR ihour  (I) : heures du calcul
c*PAR imin   (I) : minutes du calcul
c*PAR isec   (I) : secondes du calcul
c*
c*PAR xikm   (I) : coordonnee inertielle en x (kilometres)
c*PAR yikm   (I) : coordonnee inertielle en y (kilometres)
c*PAR zikm   (I) : coordonnee inertielle en z (kilometres)
c*
c*PAR rig    (I) : matrice de passage du repere inertiel
c*PAR            : au repere geographique  
c*PAR rgdip  (I) : matrice (3,3) de passage du repere geographique
c*PAR           : au repere dipolaire
c*
c*PAR rgsm   (I) : matrice de passage du repere geocentrique
c*PAR            : au repere solaire magnetique
c*PAR rggs   (I) : matrice de passage du repere geocentrique
c*PAR            : au repere solaire magnetosph
c*PAR rgse   (I) : matrice de passage du repere geocentrique
c*PAR            : au repere solaire ecliptique
c*
c*PAR xi     (O) : coordonnee inertielle en x (rayons terrestres)
c*PAR yi     (O) : coordonnee inertielle en y (rayons terrestres)
c*PAR zi     (O) : coordonnee inertielle en z (rayons terrestres)
c*
c*PAR xg     (O) : coordonnee geographique en x (rayons terrestres)
c*PAR yg     (O) : coordonnee geographique en y (rayons terrestres)
c*PAR zg     (O) : coordonnee geographique en z (rayons terrestres)
c*
c*PAR rre    (O) : distance radiale geocentrique (rayons terrestres)
c*PAR thetr  (O) : colatitude geocentrique (radians) 
c*PAR phir   (O) : longitude geocentrique (radians)
c*
c*PAR xlatgm (O) : latitude geomagnetique (radians)
c*PAR xlongm (O) : longitude geomagnetique (radians)
c*
c*PAR xse    (O) : coordonnee solaire ecliptique en x (rayons terrestres)
c*PAR yse    (O) : coordonnee solaire ecliptique en y (rayons terrestres)
c*PAR zse    (O) : coordonnee solaire ecliptique en z (rayons terrestres)
c*
c*PAR xsm    (O) : coordonnee solaire magnetique en x (rayons terrestres)
c*PAR ysm    (O) : coordonnee solaire magnetique en y (rayons terrestres)
c*PAR zsm    (O) : coordonnee solaire magnetique en z (rayons terrestres)
c*
c*PAR xgsm   (O) : coordonnee solaire magnetospherique en x (rayons terrestres)
c*PAR ygsm   (O) : coordonnee solaire magnetospherique en y (rayons terrestres)
c*PAR zgsm   (O) : coordonnee solaire magnetospherique en z (rayons terrestres)
c*
c*PAR tglsa  (O) : temps geomagnetique local (heures fractionaires)
c*PAR tlsat  (O) : temps local du satellite (heures fractionaires)
c*
c*PAR xlats  (O) : latitude dans le systeme solaire ecliptique (radians)
c*PAR xlons  (O) : longitude dans le systeme solaire ecliptique (radians)
c*
c*PAR tlose  (O) : temps local en gse (heures fractionaires)
c*
c*PAR ier    (O) : code de retour
c*
c*NOT ier        : sans objet
c*
c*NOT common     : util
c*
c*INF utilise    : promal, carsp, angleg, ggeom, tgml, tlocal
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.05.30 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      integer ihour,imin,isec
      double precision xikm,yikm,zikm
      double precision rig(3,3),rgdip(3,3)
      double precision rgsm(3,3),rggsm(3,3),rgse(3,3)
      double precision xi,yi,zi
      double precision xg,yg,zg
      double precision rre,thetr,phir
      double precision xlatgm,xlongm
      double precision xse,yse,zse
      double precision xsm,ysm,zsm
      double precision xgsm,ygsm,zgsm
      double precision tglsat,tlsat
      double precision xlatse,xlonse
      double precision tlose
      integer ier 
c
c     ----------------------------------
c*FON Declaration des variables communes
c     ----------------------------------
c
      double precision pi,dpi,rad,deg,pid,xmu,rayt
c
c*COM pi   : constante pi (obtenue a partir de acos(-1.))
c*COM dpi  : constante 2 * pi
c*COM pid  : constante pi / 2
c*COM rad  : facteur de conversion degres  ----> radians
c*COM deg  : facteur de conversion radians ----> degres
c*COM xmu  : constante de gravitation terrestre (km**3/sec**2)
c*COM rayt : rayon equatorial terrestre (km)
c
      common/util/pi,dpi,rad,deg,pid,xmu,rayt
c
c     ----------------------------------
c*FON Declaration des fonctions externes
c     ----------------------------------
c
      external angleg
      double precision angleg
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier = 0
c
c      ---------------------------------------------------------
c*FON  Calcul des coordonnees geographiques du satellite en r.e.
c      ---------------------------------------------------------
c
      xi = xikm / rayt
      yi = yikm / rayt
      zi = zikm / rayt
c
      call promal(rig,xi,yi,zi,xg,yg,zg,ier)
c
c     ------------------------------------------------------
c*FON Calcul des coordonnees spheriques en rayons terrestres
c     ------------------------------------------------------
c
      call carsp(xg,yg,zg,rre,thetr,phir,ier)
c
c     ----------------------------------------
c*FON Calcul des positions dans le systeme gse
c     ----------------------------------------
c
      call promal(rgse,xg,yg,zg,xse,yse,zse,ier)
c
c     -----------------------------------------------------------
c*FON Calcul de latitude de la longitude et du temps local en gse
c     -----------------------------------------------------------
c
      xlatse = asin(zse / rre)
c
      xlonse = angleg(xse,yse,ier)
c
c     ---------------------------------------------------------------
c*FON On adopte une definition similaire a celle du temps geom. local
c*FON pour le calcul du temps local en gse
c     ---------------------------------------------------------------
c
      tlose  = (xlonse / 15.d0) + 12.d0
c
      tlose  = dmod(tlose,24.d0) 
c
c     --------------------------------------
c*FON Calcul des positions dans le repere sm
c     --------------------------------------
c
      call promal(rgsm,xg,yg,zg,xsm,ysm,zsm,ier)
c
c     ---------------------------------------
c*FON Calcul des positions dans le repere gsm
c     ---------------------------------------
c
      call promal(rggsm,xg,yg,zg,xgsm,ygsm,zgsm,ier)
c
c     --------------------------------------------------
c*FON Calcul des coordonnees geomagnetiques du satellite
c     --------------------------------------------------
c
      call ggeom(rgdip,thetr,phir,xlatgm,xlongm,ier)
c
c     -------------------------------------------------
c*FON Calcul du temps geomagnetique du satellite tglsat
c     -------------------------------------------------
c
      call tgml(rgsm,thetr,phir,tglsat,ier)
c
c     ----------------------------------------
c*FON Calcul du temps local du satellite tlsat
c     ----------------------------------------
c
      call tlocal(ihour,imin,isec,phir,tlsat,ier)
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end