PRO dustem_write_pol,dir,st,help=help
;+
; NAME:
;   dustem_write_pol
;
; PURPOSE:
;   writes information relating to model polarization parameters in the .DAT files 
;
; CATEGORY:
;    DustEMWrap, Distributed, LowLevel, Initialization
;
; CALLING SEQUENCE:
;   dustem_write_pol,dir,st
;
; INPUTS:
;    st   : dustem data structure
;    dir  : output directory where file will be written
;
; OPTIONAL INPUT PARAMETERS:
;    None
;
; OUTPUTS:
;    None
;
; OPTIONAL OUTPUT PARAMETERS:
;    None
;
; ACCEPTED KEY-WORDS:
;    help     : writes this help
;
; COMMON BLOCKS:
;    None
;
; SIDE EFFECTS:
;    Files are written
;
; RESTRICTIONS:
;    The DustEM fortran code must be installed
;    The DustEMWrap IDL code must be installed
;
; PROCEDURES AND SUBROUTINES USED:  
;
; EXAMPLES:
;
; MODIFICATION HISTORY:
;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  
;-
  
  IF keyword_set(help) THEN BEGIN
     doc_library,'dustem_write_pol'
     goto,the_end
  ENDIF

  
Ncomments=7
c=strarr(Ncomments)

c(0)='# DUSTEM: polarization parameters'
c(1)='# for f_pol and cos(theta0)'
c(2)='#'
c(3)='# atresh pstiff plev'
c(4)='# cteta0'
c(5)='# npol'
c(6)='#'

Nst=n_elements(st)

FOR i=0L,Nst-1 DO BEGIN

    ffile=st(i).file

    IF ffile NE '' THEN BEGIN

	   fv=str_sep(ffile,'/')
       file=dir+fv(n_elements(fv)-1)
    	openw,unit,file,/get_lun

    	FOR ii=0,Ncomments-1 DO printf,unit,c(ii)

    	printf,unit,st(i).atresh,st(i).pstiff,st(i).plev,format='(3(E18.10,2X))'
    	printf,unit,st(i).cteta0,format='(1E8.2)'
    	printf,unit,st(i).npol,format='(I1)'

    	close,unit
    	free_lun,unit

    ENDIF

ENDFOR

the_end:
END