FUNCTION dustem_read_circ_vg,file,silent=silent,help=help

;+
; NAME:
;   dustem_read_circ_vg
;
; PURPOSE:
;   reads information relating to stellar polarisation from the
;   appropriate .RES files
;
; CATEGORY:
;    DustEMWrap, Distributed, LowLevel, Initialization
;
; CALLING SEQUENCE:
;   st=dustem_read_circ_vg(file)
;
; INPUTS:
;    file  : file to be read
;
; OPTIONAL INPUT PARAMETERS:
;    None
;
; OUTPUTS:
;    st   : dustem data structure
;
; OPTIONAL OUTPUT PARAMETERS:
;    None
;
; ACCEPTED KEY-WORDS:
;    help     : writes this help
;
; COMMON BLOCKS:
;    None
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;    The DustEM fortran code must be installed
;    The DustEMWrap IDL code must be installed
;
; PROCEDURES AND SUBROUTINES USED:  
;
; EXAMPLES:
;
; MODIFICATION HISTORY:
;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  
;-

  IF keyword_set(help) THEN BEGIN
     doc_library,'dustem_read_circ_vg'
     st=0.
     goto,the_end
  ENDIF


  
;=== determine the number of grains
str='                               '
OPENR,unit,file,/get_lun

;==read comments
str='' & first_char='#'
WHILE first_char EQ '#' DO BEGIN
  readf,unit,str
  first_char=strmid(str,0,1)
ENDWHILE
;readf,unit,str
CLOSE,unit
free_lun,unit
str=strcompress(str)
str=strtrim(str,2)
vv=str_sep(str,' ')
Ngrains=vv(0)

;Read model output
instruc='readcol,file,wav,'
FOR i=0L,Ngrains-1 DO BEGIN
  instruc=instruc+'circ_grain_'+strtrim(i+1,2)+','
ENDFOR
;VG read circ_tot from the file
instruc=instruc+'circ_tot,silent=silent'
toto=execute(instruc)

nlines=n_elements(wav)-1

one_st = {wav:0., circ_grain:replicate(0.,Ngrains), circ_tot:0.}
st=replicate(one_st,Nlines)

st.wav=wav(1:*)
FOR iwav=0L,Nlines-1 DO BEGIN
   FOR igrain=0L,Ngrains-1 DO BEGIN
      instruc = 'st(iwav).circ_grain(igrain) = circ_grain_'+strtrim(igrain+1,2)+'(iwav)'
      toto = execute(instruc)
      instruc = 'st(iwav).circ_tot = circ_tot(iwav)'
      toto = execute(instruc)
   ENDFOR
ENDFOR

the_end:
return,st

END