FUNCTION dustem_read_all_release,dir_in,silent=silent,help=help

;+
; NAME:
;    dustem_read_all_release
; PURPOSE:
;    Reads all Dustem input data, as of the web available dustem fortran version
; CATEGORY:
;    Dustem
; CALLING SEQUENCE:
;    st=dustem_read_all_release(dir_in[,/silent])
; INPUTS:
;    dir_in: input directory
; OPTIONAL INPUT PARAMETERS:
;    None
; OUTPUTS:
;    None
; OPTIONAL OUTPUT PARAMETERS:
;    None
; ACCEPTED KEY-WORDS:
;    help      = If set, print this help
;    sielnt    = If set, keep silent
; COMMON BLOCKS:
;    None
; SIDE EFFECTS:
;    None
; RESTRICTIONS:
;    The dustem idl wrapper must be installed
; PROCEDURE:
;    None
; EXAMPLES
;    
; MODIFICATION HISTORY:
;    Written by JP Bernard
;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  
;-

IF keyword_set(help) THEN BEGIN
  doc_library,'dustem_read_all_release' 
  st=0
  goto,the_end
ENDIF

if strmid(!dustem_dat,0,/reverse) ne '/' then !dustem_dat=!dustem_dat+'/' 

dir_in_dat=dir_in+'data/'
dir_in_qabs=dir_in+'oprop/'
dir_in_capa=dir_in+'hcap/'

file=dir_in_dat+(*!dustem_inputs).grain
;st_grains=dustem_read_grain(file,silent=silent)
st_grains=dustem_read_grain(file,silent=silent,key_str=key_str,G0=G0)
Ngrains=n_elements(st_grains)

file=dir_in_dat+'ISRF.DAT'
st_isrf=dustem_read_isrf(file,silent=silent,Nisrf=Nisrf)

file=dir_in_dat+'GAS.DAT'
st_gas=dustem_read_gas(file,silent=silent)

;=== Read Qabs

st_qabs=ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
  read_densities=0
  IF st_grains[i].rho LE 0 THEN read_densities=1
  Qabs_file=dir_in_qabs+'Q_'+st_grains(i).grain_type+'.DAT'
  st=dustem_read_qabs_lv(Qabs_file,silent=silent,read_densities=read_densities)
  st_qabs(i)=ptr_new(st)
ENDFOR
;=== Read heat capacities
st_calor=ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
  Calor_file=dir_in_capa+'C_'+st_grains(i).grain_type+'.DAT'
  st=dustem_read_calor_lv(Calor_file,silent=silent)
  st_calor(i)=ptr_new(st)   
ENDFOR

;=== Read lambda
file=dir_in_qabs+'LAMBDA.DAT'
st_lambda=dustem_read_lambda(file,silent=silent)

;=== Read size distribution files
st_size=ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
  IF stregex(st_grains(i).type_keywords, 'size', /bool) THEN BEGIN
    Size_file=dir_in_dat+'SIZE_'+st_grains(i).grain_type+'.DAT'
    st=dustem_read_size(Size_file,silent=silent)
    st_size(i)=ptr_new(st)
  ENDIF ELSE BEGIN
    st_size(i) = ptr_new()
  ENDELSE
ENDFOR

;stop
;=== Read MIX files
st_mix = ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
   IF stregex(st_grains(i).type_keywords, 'mix', /bool) THEN BEGIN
      Mix_file=dir_in_dat+'MIX_'+st_grains(i).grain_type+'.DAT'
      st=dustem_read_mix(Mix_file,silent=silent)
      st_mix(i)=ptr_new(st)
   ENDIF ELSE BEGIN
      st_mix(i)=ptr_new()
   ENDELSE
ENDFOR

;=== Read CHRG files
st_chrg = ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
   IF stregex(st_grains(i).type_keywords, 'chrg', /bool) THEN BEGIN
      chrg_file=dir_in_dat+'CHRG_'+st_grains(i).grain_type+'.DAT'
      st=dustem_read_chrg(chrg_file,silent=silent)
      st_chrg(i)=ptr_new(st)
   ENDIF ELSE BEGIN
      st_chrg(i)=ptr_new()
   ENDELSE
ENDFOR

;=== Read SPIN files
st_spin = ptrarr(Ngrains)
FOR i=0L,Ngrains-1 DO BEGIN
   IF stregex(st_grains(i).type_keywords, 'spin', /bool) THEN BEGIN
      chrg_file=dir_in_dat+'SPIN_'+st_grains[i].grain_type+'.DAT'
      st=dustem_read_spin(chrg_file,silent=silent)
      st_spin[i]=ptr_new(st)
   ENDIF ELSE BEGIN
      st_spin[i]=ptr_new()
   ENDELSE
ENDFOR

;stop

;=== Read POL and Qabs files
st_qpol = ptrarr(2,Ngrains)
st_qH = ptrarr(2,Ngrains)
st_qcirc = ptrarr(Ngrains)

;=== JPB : this organisation may not be optimal
st_pol={file:'',qpol:st_qpol,qH:st_qH,qcirc:st_qcirc}
;st_pol = replicate(one_st,Ngrains)

IF !run_pol THEN BEGIN
   st_align=dustem_read_align(dir_in_dat,st_grains,silent=silent)
   FOR i=0L,Ngrains-1 DO BEGIN
      i_alig = 0
      ;IF stregex(st_grains.grains(i).type_keywords, 'pol', /bool) THEN BEGIN
      IF stregex(st_grains(i).type_keywords, 'pol', /bool) THEN BEGIN
	      IF not stregex(st_align.keywords, 'rrf', /bool) THEN BEGIN
          FOR i_axis = 1, 2 DO BEGIN
            ;Q_file=dir_in_qabs+'Q'+strtrim(i_axis,2)+'_'+st_grains.grains(i).grain_type+'.DAT'
            Q_file=dir_in_qabs+'Q'+strtrim(i_axis,2)+'_'+st_grains(i).grain_type+'.DAT'
            st=dustem_read_qabs_lv(Q_file,silent=silent)
            st_qpol(i_axis-1,i)=ptr_new(st)
          ENDFOR
        ENDIF
         
      	IF (st_align.anisG0 > 0) THEN BEGIN
          FOR i_axis = 1, 2 DO BEGIN
               ;Q_file=dir_in_qabs+'QH'+strtrim(i_axis,2)+'_'+st_grains.grains(i).grain_type+'.DAT'
               Q_file=dir_in_qabs+'QH'+strtrim(i_axis,2)+'_'+st_grains(i).grain_type+'.DAT'
               st=dustem_read_qabs_lv(Q_file,silent=silent)
               st_qH(i_axis-1,i)=ptr_new(st)
          ENDFOR
	      ENDIF

      	IF stregex(st_align.keywords, 'circ', /bool) THEN BEGIN
            ;Q_file=dir_in_qabs+'Qc_'+st_grains.grains(i).grain_type+'.DAT'
            Q_file=dir_in_qabs+'Qc_'+st_grains(i).grain_type+'.DAT'
            st=dustem_read_qabs_lv(Q_file,silent=silent)
            st_qcirc(i)=ptr_new(st)
	      ENDIF
      ENDIF ELSE BEGIN
         st_qpol(0:1,i)=ptr_new()
         st_qH(0:1,i)=ptr_new()
         st_qcirc(i)=ptr_new()
      ENDELSE
   ENDFOR
   st_pol={qpol:st_qpol,qH:st_qH,qcirc:st_qcirc}
ENDIF

;DP :ADD DTLS
one_st={file:'',a_dtls:0.,lc:0.,c_delta:0.,vt:0.,Pmu:0.,gamma_e:0.,omega_m:0.,tau_0:0.,V0:0.,Vmin:0.,Vm:0.,ldtresh:0.}
st_tls = replicate(one_st,Ngrains)

if !run_tls then begin
   FOR i=0L,Ngrains-1 DO BEGIN
      IF stregex(st_grains(i).type_keywords, 'dtls', /bool) THEN BEGIN
         TLS_file='DTLS_'+st_grains.grains(i).grain_type+'.DAT'
         st=dustem_read_tls(dir_in,TLS_file,silent=silent)
         st_tls(i)=st
      ENDIF ELSE BEGIN
         st_tls(i)=one_st
      ENDELSE
   ENDFOR
ENDIF

;=== This will become !dustem_params - MAYBE THIS WILL NEED TO BE CHANGED FOR THE G0 TREATMENT

;st={Ngrains:Ngrains,G0:G0,Keywords:key_str,grains:st_grains, $
;    isrf:st_isrf,qabs:st_qabs,calor:st_calor,lambda:st_lambda,size:st_size,mix:st_mix,chrg:st_chrg,gas:st_gas,spin:st_spin,pol:st_pol,tls:st_tls}
;VG Add NH
if !run_pol then begin
  st={Ngrains:Ngrains,G0:G0,Keywords:key_str,grains:st_grains,isrf:st_isrf,qabs:st_qabs,calor:st_calor,lambda:st_lambda,size:st_size,mix:st_mix,chrg:st_chrg,gas:st_gas,spin:st_spin,align:st_align,qpol:st_qpol,qcirc:st_qcirc,qH:st_qH,tls:st_tls}
endif else begin
  st={Ngrains:Ngrains,G0:G0,Keywords:key_str,grains:st_grains,isrf:st_isrf,qabs:st_qabs,calor:st_calor,lambda:st_lambda,size:st_size,mix:st_mix,chrg:st_chrg,gas:st_gas,spin:st_spin,tls:st_tls}
endelse

;stop

the_end:

RETURN,st

END