FUNCTION dustem_read_secteffir,file,silent=silent,help=help

;+
; NAME:
;   dustem_read_secteffir
;
; PURPOSE:
;   reads information relating to the grain cross section in the IR
;   from the corresponding .DAT file
;
; CATEGORY:
;    DustEMWrap, Distributed, LowLevel, Initialization
;
; CALLING SEQUENCE:
;   st=dustem_read_secteffir(file)
;
; INPUTS:
;    file  : input file to be read
;
; OPTIONAL INPUT PARAMETERS:
;
; OUTPUTS:
;    st   : dustem data structure
;
; OPTIONAL OUTPUT PARAMETERS:
;
; ACCEPTED KEY-WORDS:
;    help     : writes this help
;
; COMMON BLOCKS:
;    None
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;    The DustEM fortran code must be installed
;    The DustEMWrap IDL code must be installed
;
; PROCEDURES AND SUBROUTINES USED:  
;
; EXAMPLES:
;
; MODIFICATION HISTORY:
;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  
;-
  
IF keyword_set(help) THEN BEGIN
   doc_library,'dustem_read_secteffir'
   st=0.
   goto,the_end
ENDIF

  
  
Ngrains=(*!dustem_params).Ngrains
;Ngrains=3

str='readcol,file,wav_ir,'
FOR i=0L,Ngrains-1 DO BEGIN
  str=str+'sect_grain_'+strtrim(i+1,2)+','
ENDFOR
str=str+'silent=silent'

;readcol,file,wav_ir,sect_pah,sect_vsg,sect_bg,silent=silent
toto=execute(str)

nlines=n_elements(wav_ir)

str='one_st={wav:0.,'
FOR i=0L,Ngrains-1 DO BEGIN
  str=str+'sect_grain_'+strtrim(i+1,2)+':0.'
  IF i NE Ngrains-1 THEN str=str+','
ENDFOR
str=str+'}'
toto=execute(str)

;one_st={wav:0.,sect_pah:0.,sect_vsg:0.,sect_bg:0.}
st=replicate(one_st,Nlines)

st.wav=wav_ir
FOR i=0L,Ngrains-1 DO BEGIN
  str='st.(i+1)=sect_grain_'+strtrim(i+1,2)
  toto=execute(str)
ENDFOR
;st.sect_pah=sect_pah
;st.sect_vsg=sect_vsg
;st.sect_bg=sect_bg

the_end:
return,st

END