PRO dustem_plot_data_sed,_extra=extra,help=help

;+
; NAME:
;    dustem_plot_data_sed
; PURPOSE:
;    Plots Dustem SED data
; CATEGORY:
;    Dustem
; CALLING SEQUENCE:
;    dustem_plot_data_sed[,/help][_extra=]
; INPUTS:
;    None
; OPTIONAL INPUT PARAMETERS:
;    _extra    = extra parameters for the plot routine
; OUTPUTS:
;    None
; OPTIONAL OUTPUT PARAMETERS:
;    None
; ACCEPTED KEY-WORDS:
;    help      = If set, print this help
; COMMON BLOCKS:
;    None
; SIDE EFFECTS:
;    SED and model are plotted
; RESTRICTIONS:
;    The dustem idl wrapper must be installed
; PROCEDURE:
;    None
; EXAMPLES
;    dustem_plot_data_sed
; MODIFICATION HISTORY:
;    Written by J.-Ph. Bernard June 10 2011
;    see evolution details on the dustem cvs maintained at CESR
;    Contact J.-Ph. Bernard (Jean-Philippe.Bernard@cesr.fr) in case of problems.
;-

IF keyword_set(help) THEN BEGIN
  doc_library,'dustem_plot_data_sed'
  goto,the_end
ENDIF

use_col_data_spec=255   ;color for spectral data
use_col_data_filt=100   ;color for filter data

wav=(*(*!dustem_data).sed).wav
values=(*(*!dustem_data).sed).values
filt_names=(*(*!dustem_data).sed).filt_names
sigma=(*(*!dustem_data).sed).sigma

cgplot,wav,values,/nodata,_extra=extra,/xlog,/ylog
ind_filt=where(filt_names NE 'SPECTRUM',count_filt)
ind_spec=where(filt_names EQ 'SPECTRUM',count_spec)

;=== Plot the data
IF count_spec NE 0 THEN BEGIN
  plotsym,0,/fill

  cgoplot,wav[ind_spec],values[ind_spec],psym=8,_extra=extra,color=use_col_data_spec,syms=0.5

  IF not keyword_set(no_spec_error) THEN BEGIN

    err_bar,wav[ind_spec],values[ind_spec],yrms=3.*sigma[ind_spec]/2.,color=use_col_data_spec

  ENDIF
ENDIF
IF count_filt NE 0 THEN BEGIN
  plotsym,0,/fill

  cgoplot,wav[ind_filt],values[ind_filt],psym=8,_extra=extra,color=use_col_data_filt
  err_bar,wav[ind_filt],values[ind_filt],yrms=3.*sigma[ind_filt]/2.,color=use_col_data_filt

ENDIF

the_end:

END