FUNCTION dustem_compute_stokes,p_dim,st,dustem_qsed,dustem_used,Q_spec,U_spec,out_st=out_st,_extra=extra

;+
; NAME:
;    dustem_compute_stokes
; PURPOSE:
;    Provides Stokes Q and Stokes U dustem spectra and wrapper SEDs 
; CATEGORY:
;    Dustem
; CALLING SEQUENCE:
;    out=dustem_compute_polsed(p_dim[,st=][,_extra=][,/help])
; INPUTS:
;    p_dim      = parameter values
; OPTIONAL INPUT PARAMETERS:
;    stp        = Dustem structure
; OUTPUTS:
;    sed         : computed SED for filters in !dustem_data
;    dustem_qsed : SED in Q
;    dustem_used : SED in U
; OPTIONAL OUTPUT PARAMETERS:
;    stp        = Dustem output structure
; ACCEPTED KEY-WORDS:
;    help      = If set, print this help
; COMMON BLOCKS:
;    None
; SIDE EFFECTS:
;    None
; RESTRICTIONS:
;    The dustem idl wrapper must be installed
; PROCEDURE:
;    None
; EXAMPLES
;    
; MODIFICATION HISTORY:
;    Written by J.-Ph. Bernard
;    see evolution details on the dustem cvs maintained at CESR
;    Contact J.-Ph. Bernard (Jean-Philippe.Bernard@cesr.fr) in case of problems.

IF keyword_set(help) THEN BEGIN
    doc_library,'dustem_compute_stokes'
    out=0.
    goto,the_end
ENDIF

IF not keyword_set(st) THEN BEGIN

    dustem_activate_plugins,p_dim/(*(*!dustem_fit).param_init_values)

    st=dustem_run(p_dim)

ENDIF

out=0.

If keyword_set(result) THEN result=st

fact = 1.e4*(*!dustem_HCD)/(4.*!pi)/(3.e8/1.e-6/(st.sed).wav)*1.e20/1.e7

stI = st.sed.em_tot * fact    ;This is Total intensity I
P = st.polsed.em_tot * fact   ;This is Polarized intensity P

Nwaves=(size(stI))[1]

frac=P/stI
tes=where(finite(frac) eq 0)
frac(tes)=0.

FOR i=0L,n_tags(*!dustem_scope)-1 DO BEGIN   
    

    IF total(strsplit((*(*!dustem_scope).(i)),'+',/extract) EQ 'REPLACE_POLSED') THEN BEGIN

        
        Q_spec=(*(*!dustem_plugin).(i))[*,1]

        U_spec=(*(*!dustem_plugin).(i))[*,2]

        
    ENDIF 

ENDFOR    

IF ~isa(Q_spec) && ~isa(U_spec) THEN polar_ippsi2iqu,stI,Q_spec,U_spec,frac,replicate(!dustem_psi,Nwaves) ;This line is to generate data by default.

        
FOR i=0L,n_tags(*!dustem_scope)-1 DO BEGIN

    IF total(strsplit((*(*!dustem_scope).(i)),'+',/extract) EQ 'ADD_POLSED') THEN BEGIN
        

        Q_spec+=(*(*!dustem_plugin).(i))[*,1]

        U_spec+=(*(*!dustem_plugin).(i))[*,2]

    ENDIF

ENDFOR

;stop

;-----------------------------------------

;INITIALIZING THE STOKES SEDS

dustem_qsed = (*!dustem_data.qsed).values * 0.
dustem_used = (*!dustem_data.used).values * 0.

if not isarray(stI) THEN stop ; I don't get this test. It is unnecessary.

;Performing color corrections on the dustem spectra and generating the SEDs at the given filters 

IF !dustem_do_cc NE 0 AND !dustem_never_do_cc EQ 0 THEN BEGIN
    message,'DOING color correction calculations',/info
ENDIF ELSE BEGIN
          message,'SKIPPING color correction calculations',/info
      ENDELSE

ind_qsed=where((*!dustem_data.qsed).filt_names NE 'SPECTRUM',count_qsed)
ind_used=where((*!dustem_data.used).filt_names NE 'SPECTRUM',count_used)

  
IF count_qsed NE 0 THEN BEGIN 
  filter_names=((*!dustem_data.qsed).filt_names)(ind_qsed)    

  if isa(dustem_qsed) then begin 

    sqsed=dustem_cc(st.polsed.wav,Q_spec,filter_names,cc=cc)

    dustem_qsed(ind_qsed)=sqsed

  endif

ENDIF

IF count_used NE 0 THEN BEGIN
filter_names=((*!dustem_data.used).filt_names)(ind_used)
if isa(dustem_used) then begin
  sused=dustem_cc(st.polsed.wav,U_spec,filter_names,cc=cc)
  dustem_used(ind_used)=sused
endif

ENDIF

;For spectrum data points, interpolate in log-log
;Linear interpolation leads to wrong values, in particular where few
;wavelengths points exist in the model (long wavelengths).

ind_qspec=where((*!dustem_data.qsed).filt_names EQ 'SPECTRUM',count_qspec)
ind_uspec=where((*!dustem_data.used).filt_names EQ 'SPECTRUM',count_uspec)

IF count_qspec NE 0 THEN BEGIN
  if isa(dustem_qsed) then dustem_qsed(ind_qspec)=interpol(Q_spec,st.polsed.wav,(((*!dustem_data.qsed).wav)(ind_qspec)))  
ENDIF
IF count_uspec NE 0 THEN BEGIN
if isa(dustem_used) then dustem_used(ind_uspec)=interpol(U_spec,st.polsed.wav,(((*!dustem_data.used).wav)(ind_uspec)))

ENDIF

out_st=st

;clean pointers
heap_gc

the_end:

RETURN,out

END