FUNCTION dustem_compute_sed,p_dim,$

                            st=st,$

                            sed_spec=sed_spec, $

                            use_previous_fortran=use_previous_fortran, $

                            help=help

;+
; NAME:
;    dustem_compute_sed

;

; PURPOSE:

;    Computes a SED for a given Dustem model

;

; CATEGORY:
;    Dustem

;

; CALLING SEQUENCE:

;    sed=dustem_compute_sed(p_dim[,st][,sed_spec][,/help])

;

; INPUTS:

;    p_dim      = parameter values

;

; OPTIONAL INPUT PARAMETERS:

;    st        = Dustem Fortran output structure

;

; OUTPUTS:
;    sed       = computed SED for filters in !dustem_data

;

; OPTIONAL OUTPUT PARAMETERS:

;    st      = dustem output structure

;    sed_spec    = dustem emission spectrum

;

; ACCEPTED KEY-WORDS:

;    use_previous_fortran = if set, uses the output of the previous fortran run, and does not run the fortran.

;    help      = If set, print this help

;

; COMMON BLOCKS:
;    None

;

; SIDE EFFECTS:
;    None

;

; RESTRICTIONS:

;    The DustEMWrap IDL code must be installed
;

; PROCEDURE:
;    None

;

; EXAMPLES
;    
; MODIFICATION HISTORY:

;    Written by J.-Ph. Bernard 2008

;    Evolution details on the DustEMWrap gitlab.
;    See http://dustemwrap.irap.omp.eu/ for FAQ and help.  

;-

IF keyword_set(help) THEN BEGIN
  doc_library,'dustem_compute_sed'
  dustem_sed=0.
  goto,the_end
ENDIF

IF not keyword_set(st) THEN BEGIN

   dustem_activate_plugins,p_dim/(*(*!dustem_fit).param_init_values),st=st,use_previous_fortran=use_previous_fortran

ENDIF

; Convert into MJy/sr/1d20

fact = 1.e4*(*!dustem_HCD)/(4.*!pi)/(3.e8/1.e-6/st.sed.wav)*1.e20/1.e7 ;this is correct despite the way it is presented (1.e4/1e.7*1e.20=1.e17 which is the factor to convert from ergs to Mega Janskys)

SED_spec = st.sed.em_tot * fact

;===== Adding plugin output to spectrum ----------------

Nplugins=n_elements(*!dustem_plugin)
scopes=(*!dustem_plugin).scope

;stop

IF scopes[0] NE 'NONE' THEN BEGIN

  FOR i=0L,Nplugins-1 DO BEGIN
    IF total(strsplit((*!dustem_plugin)[i].scope,'+',/extract) eq 'ADD_SED') THEN BEGIN
      SED_spec+=(*(*!dustem_plugin)[i].spec)[*,0]
    ENDIF
  ENDFOR

ENDIF

;------------------------------------------

IF not isarray(SED_spec) THEN stop

;COMPUTE THE MODEL SED

;JPB: problem there: we should be able to compute an SED even when there is no data in !dustem_data

dustem_sed = (*(*!dustem_data).sed).values * 0.

IF !dustem_do_cc NE 0 AND !dustem_never_do_cc EQ 0 THEN BEGIN
  message,'DOING color correction calculations',/info
ENDIF ELSE BEGIN
  message,'SKIPPING color correction calculations: we take previous values of cc',/info
ENDELSE

ind_sed=where((*(*!dustem_data).sed).filt_names NE 'SPECTRUM' and (*(*!dustem_data).sed).wav gt 0.,count_sed)

IF count_sed NE 0 THEN BEGIN

  filter_names=((*(*!dustem_data).sed).filt_names)[ind_sed]

  ssed=dustem_cc(st.sed.wav,SED_spec,filter_names,cc=cc)  

  dustem_sed[ind_sed]=ssed

ENDIF ELSE BEGIN

  print,"**** WARNING **** NO FILTER defined in DATA for COLOUR CORRECTION" 

ENDELSE

;For spectrum data points, interpolate in log-log
;Linear interpolation leads to wrong values, in particular where few
;wavelengths points exist in the model (long wavelengths).

ind_spec=where((*(*!dustem_data).sed).filt_names EQ 'SPECTRUM',count_spec)

IF count_spec NE 0 THEN BEGIN

    dustem_sed[ind_spec]=interpol(SED_spec,st.sed.wav,(((*(*!dustem_data).sed).wav)[ind_spec]))

    ;dustem_sed(ind_spec)=10^interpol(alog10(spec),alog10(st.sed.wav),alog10((((*!dustem_data.sed).wav)(ind_spec))))

ENDIF
out_st=st

;clean pointers
heap_gc

the_end:

;VG : error in cc IRAS1 when no PAH 

; j=where(dustem_sed ne dustem_sed,count)
; if count gt 0 then dustem_sed[j]=0.

;stop

RETURN,dustem_sed

END