FUNCTION dustem_plugin_synchrotron,key=key,val=val,scope=scope,help=help

;+
; NAME:

;    dustem_plugin_synchrotron

; PURPOSE:

;    DUSTEM plugin to compute synchrotron emission

; CATEGORY:
;    DUSTEM Wrapper
; CALLING SEQUENCE:

;    synch=dustem_plugin_synchrotron([,key=][,val=])

; INPUTS:
;    None
; OPTIONAL INPUT PARAMETERS:
;    key  = input parameter number
;    val  = input parameter value
; OUTPUTS:
;    synch = synch spectrum (on dustem wavelengths)
; OPTIONAL OUTPUT PARAMETERS:
;    None
; ACCEPTED KEY-WORDS:
;    help                  = if set, print this help
; COMMON BLOCKS:
;    None
; SIDE EFFECTS:
;    None
; RESTRICTIONS:
;    None
; PROCEDURE:

;    This is a dustem plugin

; EXAMPLES
;
; MODIFICATION HISTORY:
;    Written by JPB 
;-

IF keyword_set(help) THEN BEGIN

  doc_library,'dustem_plugin_synchrotron'

  output=0.
  goto,the_end
ENDIF

;default values of input parameters
s=3           ;power spectrum of CR E distribution

A=1           ;Synchrotron radiation amplitude at 10 mm

psi=0.        ;default polarization angle
smallp=0.3    ;default polarization fraction

IF keyword_set(key) THEN BEGIN 

  ind1=where(key EQ 1,count1)
  ind2=where(key EQ 2,count2)
  ind3=where(key EQ 3,count3)

  ind4=where(key EQ 4,count4)

  IF count1 NE 0 then s=val[ind1[0]] ;else s=3
  IF count2 NE 0 then A=val[ind2[0]] ;else A=1
  IF count3 NE 0 then smallp=val[ind3[0]] 
  IF count4 NE 0 then BEGIN
  psi=val[ind4[0]]
  print, 'psi in synchro plugin is:'
  print,psi
  ENDIF

ENDIF

lambir=dustem_get_wavelengths()
Nwavs=n_elements(lambir)

cmic=3.e14
nu=cmic/lambir
lambir_ref=10000.

;see Deschenes et al 2008, eq 6

output=fltarr(Nwavs,4)

output[*,0]=nu^(-(s+3.)/2.)
norm=interpol(output[*,0],lambir,lambir_ref)
output[*,0]=A*output[*,0]/norm

;polarization this actually need to 

polar_ippsi2iqu,output[*,0],Q,U,replicate(smallp,Nwavs),replicate(psi,Nwavs)

output[*,1]=Q

output[*,2]=U

output[*,3]=output[*,0]*smallp ;polarized part of the synchrotron emission

scope='ADD_SED+ADD_POLSED+ADD_QSED+ADD_USED'

;scope=((*!dustem_scope).synchrotron)

;if keyword_set(scope) then

the_end:
RETURN,output
  
END