subroutine roise (alfas,deltas,obliq,rise,rsei,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.06.05 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - juin 1995    
c*AUT port. CISI 
c*
c*ROL Theme : Changements de repere
c*ROL         Calcul de la matrice de passage du repere inertiel
c*ROL         au repere solaire ecliptique et de la matrice inverse.
c*
c*PAR alfas  (I) : ascension droite du soleil (radians)
c*PAR deltas (I) : declinaison du soleil (radians)
c*PAR obliq  (I) : obliquite de l'ecliptique (radians)
c*
c*PAR rise   (O) : matrice (3,3) de passage du repere inertiel  
c*PAR            : au repere solaire ecliptique
c*PAR rsei   (O) : matrice (3,3) de passage du repere solaire
c*PAR            : ecliptique au repere inertiel
c*
c*PAR ier    (O) : code de retour
c*
c*NOT ier        : sans objet
c*
c*INF utilise    : sans objet
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.06.05 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      double precision alfas, deltas, obliq 
      double precision rise(3,3), rsei(3,3)
      integer ier 
c
c     ---------------------------------
c*FON Declaration des variables locales
c     ---------------------------------
c
      integer i,j
c*LOC i,j : indices de boucles
c
      double precision sobliq,cobliq
      double precision sl,cl
c*LOC Variables de travail intermediaires
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier = 0
c
      sobliq = sin(obliq)
      cobliq = cos(obliq)
c
      sl = sin(deltas) / sobliq
      cl = cos(alfas) * cos(deltas)
c
c     -------------------------
c*FON Calcul de la matrice rise
c     -------------------------
c
      rise(1,1) =  cl
      rise(1,2) =  cobliq * sl
      rise(1,3) =  sobliq * sl
      rise(2,1) = -sl
      rise(2,2) =  cobliq * cl
      rise(2,3) =  sobliq * cl
      rise(3,1) =  0.d0
      rise(3,2) = -sobliq
      rise(3,3) =  cobliq
c
c     -------------------------------
c*FON Calcul de la matrice transposee 
c     -------------------------------
c
      do 10 i =1, 3
         do  20 j =1, 3
            rsei(i,j) = rise(j,i)
20       continue
10    continue
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end