subroutine rbelt (xbelt,tetdip,phidip,rmag,thetr,phir,iallen,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.06.05 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - janvier 1991
c*AUT port. CISI
c*
c*ROL Theme : Frontieres et regions
c*ROL         Test d'appartenance d'un satellite a la ceinture
c*ROL         de radiations magnetiques de Van Allen.
c*
c*PAR xbelt  (I) : valeur de la limite externe de la ceinture
c*PAR            : xbelt = +3.5 ou xbelt = +6. (rayons terrestres)
c*
c*PAR tetdip (I) : colatitude geocentrique du point ou le dipole
c*                 coupe l'hemisphere nord (radians)
c*PAR phidip (I) : longitude geocentrique du point ou le dipole
c*                 coupe l'hemisphere nord (radians)
c*
c*PAR rmag   (I) : distance geocentrique du satellite (rayons terrestres)
c*PAR thetr  (I) : latitude geocentrique du satellite (radians)
c*PAR phir   (I) : longitude geocentrique du satellite (radians)
c*
c*PAR iallen (O) : indicateur d'appartenance du satellite a la ceinture
c*PAR            : de radiations magnetiques de Van Allen
c*
c*PAR ier    (O) : code de retour
c*
c*NOT tetdip et phidip definissent l'orientation du dipole dans le
c*NOT repere geographique.
c*NOT Le satellite est donne par ses coordonnees spheriques terrestres.
c*
c*NOT iallen     : 0 = satellite a l'exterieur de la ceinture de Van Allen
c*NOT iallen     : 1 = satellite a l'interieur de la ceinture de Van Allen
c*
c*NOT ier        : sans objet
c*
c*INF utilise    : sans objet
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.06.05 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      double precision xbelt, tetdip, phidip, rmag, thetr, phir
      integer iallen
      integer ier
c
c     ---------------------------------
c*FON Declaration des variables locales
c     ---------------------------------
c
      double precision ctetd,stetd,cdpt,dptr,sdpt,xld
c*LOC Variables de travail intermediaires
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier    = 0
      iallen = 0
c
c     ----------------------------------------------------
c*FON Calcul des cosinus directeurs de la direction tetdip
c     ----------------------------------------------------
c
      ctetd = cos(tetdip)
      stetd = sin(tetdip)
c
c     ----------------------------------
c*FON Calcul de la position du satellite
c     ----------------------------------
c
      cdpt = ctetd * cos(thetr) +
     >       stetd * sin(thetr) * cos(phir - phidip)
c
      if (cdpt .lt. 0.95d0) then
c
         dptr = acos(cdpt)
         sdpt = sin(dptr)
         xld  = rmag / sdpt / sdpt
c
c     ---------------------------------------------------------------
c*FON Determination de l'appartenance d'un satellite a la ceinture de
c*FON radiation de Van Allen
c     ---------------------------------------------------------------
c
         if (xld .gt. xbelt) then
            iallen = 0
         else
            iallen = 1
         endif
c
      endif
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end