subroutine posns (tilt,xgsm,ygsm,zgsm,dznsh,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.05.31 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - juin 1995
c*AUT port. CISI
c*
c*ROL Theme : Frontieres et regions
c*ROL         Calcul de la position du satellite par rapport a la
c*ROL         couche neutre suivant l'axe solaire magnetospherique z
c*ROL         (l'epaisseur physique de la couche neutre est de 1 rayon
c*ROL         geocentrique terrestre).
c*
c*PAR tilt  (I) : angle de tilt (radians)
c*
c*PAR xgsm  (I) : coordonnee solaire magnetospherique x du satellite
c*PAR           : (rayons terrestres)
c*PAR ygsm  (I) : coordonnee solaire magnetospherique y du satellite
c*PAR           : (rayons terrestres)
c*PAR zgsm  (I) : coordonnee solaire magnetospherique z du satellite
c*PAR           : (rayons terrestres)
c*
c*PAR dznsh (O) : distance du satellite par rapport a la couche
c*PAR           : neutre suivant l'axe z solaire magnetospherique
c*PAR           : (rayons terrestres)
c*
c*PAR ier   (O) : code de retour
c*
c*NOT Le modele de couche neutre est celui de Fairfield
c*
c*NOT ier       : sans objet
c*
c*INF utilise   : sans objet
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.05.31 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      double precision tilt
      double precision xgsm, ygsm, zgsm
      double precision dznsh
      integer ier
c
c     ---------------------------------
c*FON Declaration des variables locales
c     ---------------------------------
c
      double precision ho,yo,rlim,radic,dd,aygsm,znsh
      double precision rp
c*LOC Variables de travail intermediaires
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     --------------------------
c*FON Affectation des constantes
c     --------------------------
c
      data ho /10.5d0/
      data yo /22.5d0/
      data dd /14.0d0/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier = 0
c
c     -----------------------------------------------------
c*FON Determination de la position du satellite par rapport
c*FON a la couche de plasma et a la couche neutre
c     -----------------------------------------------------
c
      znsh  = -dd * sin(tilt)
      rlim  =  ho * cos(tilt)
      dznsh =  999.0d0
c
      if (xgsm .lt. 0.d0) then
c
         rp = sqrt(xgsm * xgsm + ygsm * ygsm)
c
         if (rp .gt. rlim) then
c
            aygsm = abs(ygsm)
c
            if (aygsm .lt. yo) then
               radic = 1.d0 - (aygsm / yo)**2
               znsh  = ((ho + dd) * sqrt(radic) - dd) * sin(tilt)
            endif  
c
            dznsh = zgsm - znsh
c
         endif
c
      endif
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end