subroutine rogdip (tetdip,phidip,rgdip,rdipg,ier)
c*
c***********************************************************************
c*
c*          "Copyright [c] CNES 98 - tous droits reserves"
c*          **********************************************
c*
c*PRO MAGLIB
c*
c*VER 99.03.31 - V 1.0
c*VER 01.06.05 - V 2.0
c*VER 03.01.06 - V 2.1
c*
c*AUT spec. CNES - JC KOSIK - janvier 1991
c*AUT port. CISI
c*
c*ROL Theme : Changements de repere
c*ROL         Calcul de la matrice de passage du repere geocentrique
c*ROL         au repere dipolaire et de la matrice inverse.
c*
c*PAR tetdip (I) : colatitude geocentrique du point ou le dipole
c*PAR            : coupe l'hemisphere nord (radians)
c*PAR phidip (I) : longitude geocentrique du point ou le dipole
c*PAR            : coupe l'hemisphere nord (radians)
c*
c*PAR rgdip  (O) : matrice (3,3) de passage du repere geographique
c*PAR            : au repere dipolaire
c*PAR rdipg  (O) : matrice (3,3) de passage du repere dipolaire
c*PAR            : au repere geocentrique
c*
c*PAR ier    (O) : code de retour
c*
c*NOT ier        : sans objet
c*
c*INF utilise    : sans objet
c*
c*HST version 1.0 - 99.03.31 - creation de la maglib au CDPP
c*HST version 2.0 - 01.06.05 - correction de commentaires de code
c*HST version 2.1 - 03.01.06 - corrections en compilation avec g77
c*
c***********************************************************************
c*
      implicit none
c
c     ---------------------------------
c*FON Declaration identificateur rcs_id
c     ---------------------------------
c
      character rcs_id*100
c
c     --------------------------
c*FON Declaration des parametres
c     --------------------------
c
      double precision tetdip, phidip
      double precision rgdip(3,3), rdipg(3,3)
      integer ier
c
c     ---------------------------------
c*FON Declaration des variables locales
c     ---------------------------------
c
      integer i,j
c*LOC i,j : indices de boucles
c
      double precision ctetd,stetd,cphid,sphid
c*LOC Variables de travail intermediaires
c
      SAVE
c
c     ---------------------------------
c*FON Affectation identificateur rcs_id
c     ---------------------------------
c
      data rcs_id /"
     >$Id$"/
c
c     ******************
c     Debut de programme
c     ******************
c
      ier = 0
c
c     ----------------------------------------------
c*FON Calculs intermediaires (angles de la rotation)
c     ----------------------------------------------
c
      ctetd = cos(tetdip)
      stetd = sin(tetdip)
      cphid = cos(phidip)
      sphid = sin(phidip)
c
c     --------------------------
c*FON Calcul de la matrice rgdip
c     --------------------------
c
      rgdip(1,1) =  ctetd * cphid
      rgdip(1,2) =  ctetd * sphid
      rgdip(1,3) = -stetd
      rgdip(2,1) = -sphid
      rgdip(2,2) =  cphid
      rgdip(2,3) =  0.d0
      rgdip(3,1) =  stetd * cphid
      rgdip(3,2) =  stetd * sphid
      rgdip(3,3) =  ctetd
c
c     ----------------------------------------------
c*FON Calcul de la matrice rdipg transposee de rgdip
c     ----------------------------------------------
c
      do 10 i = 1, 3
         do 20 j = 1, 3
            rdipg(i,j) = rgdip(j,i)
20       continue
10    continue
c
c     ****************
c     Fin de programme
c     ****************
c
      return
      end